#include <SPI.h>
#include <RF24.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SH110X.h>
#include "MorseLib.h"

#define BTN       3    // mode toggle (Send / Receive)
#define MORSE_BTN 2    // Morse code input

#define DOT_THRESHOLD  200   // ms — short press = dot
#define LETTER_GAP     600   // ms — pause between letters
#define WORD_GAP       1400  // ms — pause triggers word send

RF24 radio(9, 10);
const byte addr[6] = "00001";

radio.setAutoAck(false);
radio.setPALevel(RF24_PA_LOW);
radio.setDataRate(RF24_250KBPS);
radio.setChannel(100);

Adafruit_SH1106G display(128, 64, &Wire, -1);

bool isTx = false;              // true = Tx mode, false = Rx mode

char currentSymbol[10] = "";   // stores dots and dashes
char txText[32]       = "";   // message to transmit
char rxText[64]       = "";   // received message

unsigned long lastHbTime = 0;  // heartbeat timer
unsigned long lastRxTime = 0;  // last received signal

void setup() {
  Serial.begin(9600);

  pinMode(BTN,       INPUT_PULLUP);
  pinMode(MORSE_BTN, INPUT_PULLUP);

  display.begin(0x3C, true);
  display.clearDisplay();
  display.setCursor(0, 0);
  display.println("I AM Rx");
  display.display();

  if (!radio.begin()) while (1);

  radio.openWritingPipe(addr);
  radio.openReadingPipe(0, addr);
  radio.startListening();
}

bool currBtn = digitalRead(BTN);

if (prevBtn == HIGH && currBtn == LOW) {
  isTx = !isTx;

  if (isTx) { radio.stopListening(); }
  else       { radio.startListening(); }

  delay(300);
}

char hb[] = "#";
radio.write(hb, sizeof(hb));
lastHbTime = millis();

char decoded = MorseLib::decode(currentSymbol);
txText[txIndex++] = decoded;
txText[txIndex]   = '\0';

radio.write(txText, strlen(txText) + 1);

if (radio.available()) {
  char msg[32] = "";
  radio.read(msg, sizeof(msg));
}

if (strcmp(msg, "#") == 0) {
  lastRxTime = millis();  // sender is active
}

strncat(rxText, msg, sizeof(rxText) - strlen(rxText) - 1);

if (millis() - lastRxTime > 3000) {
  rxText[0] = '\0';  // clears old message after 3 s
}

#include <SPI.h>
#include <RF24.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SH110X.h>
#include "MorseLib.h"

#define BTN            3
#define MORSE_BTN      2
#define DOT_THRESHOLD  200
#define LETTER_GAP     600
#define WORD_GAP       1400

RF24 radio(9, 10);
const byte addr[6] = "00001";
Adafruit_SH1106G display(128, 64, &Wire, -1);

// ---- STATE ----
bool isTx           = false;
bool prevBtn        = HIGH;
bool txInit         = false;
bool rxInit         = false;
bool indicatorState = false;

unsigned long lastBlinkTime = 0;
bool          blinkState    = false;
unsigned long lastRxTime   = 0;
const int     holdTime      = 1500;

// ---- MORSE TX ----
char currentSymbol[10] = "";
int  symbolIndex       = 0;
char txText[32]        = "";
int  txIndex           = 0;

unsigned long pressStart     = 0;
unsigned long lastRelease    = 0;
bool          lastMorseState = HIGH;

// ---- RX ----
char rxText[64] = "";

void setup() {
  Serial.begin(9600);
  pinMode(BTN,       INPUT_PULLUP);
  pinMode(MORSE_BTN, INPUT_PULLUP);

  display.begin(0x3C, true);
  display.clearDisplay();
  display.setTextColor(SH110X_WHITE);
  display.setTextSize(1);
  display.setCursor(0, 0);
  display.println("I AM Rx");
  display.display();

  if (!radio.begin()) while (1);
  radio.setAutoAck(false);
  radio.setPALevel(RF24_PA_LOW);
  radio.setDataRate(RF24_250KBPS);
  radio.setChannel(100);
  radio.openWritingPipe(addr);
  radio.openReadingPipe(0, addr);
  radio.startListening();
}

void loop() {

  // ---- MODE TOGGLE ----
  bool currBtn = digitalRead(BTN);
  if (prevBtn == HIGH && currBtn == LOW) {
    isTx = !isTx;
    if (isTx) { radio.stopListening(); txInit = false; }
    else       { radio.startListening(); rxInit = false; }
    delay(300);
  }
  prevBtn = currBtn;

  // ================= TX =================
  if (isTx) {

    if (!txInit) {
      display.clearDisplay();
      display.setCursor(0, 0);
      display.println("I AM Tx");
      display.display();
      txInit = true;
    }

    // heartbeat
    char hb[] = "#";
    radio.write(&hb, sizeof(hb));

    bool curr = digitalRead(MORSE_BTN);

    if (lastMorseState == HIGH && curr == LOW)  { pressStart = millis(); }

    if (lastMorseState == LOW && curr == HIGH) {
      unsigned long duration = millis() - pressStart;
      if (symbolIndex < 9) {
        currentSymbol[symbolIndex++] = (duration < DOT_THRESHOLD) ? '.' : '-';
        currentSymbol[symbolIndex]   = '\0';
      }
      lastRelease = millis();
    }

    unsigned long gap = millis() - lastRelease;

    if (symbolIndex > 0 && gap > LETTER_GAP && gap < WORD_GAP) {
      char decoded = MorseLib::decode(currentSymbol);
      if (txIndex < 31) { txText[txIndex++] = decoded; txText[txIndex] = '\0'; }
      symbolIndex = 0; currentSymbol[0] = '\0';
    }

    if (txIndex > 0 && gap > WORD_GAP) {
      radio.write(&txText, sizeof(txText));
      txIndex = 0; txText[0] = '\0';
    }

    display.fillRect(0, 16, 128, 32, SH110X_BLACK);
    display.setCursor(0, 16); display.println(currentSymbol);
    display.setCursor(0, 28); display.println(txText);
    display.display();
    lastMorseState = curr;

    if (millis() - lastBlinkTime > 500) {
      lastBlinkTime = millis(); blinkState = !blinkState;
      display.fillRect(0, 48, 128, 16, SH110X_BLACK);
      if (blinkState) { display.setCursor(0, 48); display.println("[SENDING]"); }
      display.display();
    }

  // ================= RX =================
  } else {

    if (radio.available()) {
      char msg[32] = "";
      radio.read(&msg, sizeof(msg));

      if (strcmp(msg, "#") == 0) {
        lastRxTime = millis();
      } else {
        strncat(rxText, msg, sizeof(rxText) - strlen(rxText) - 1);
        display.fillRect(0, 16, 128, 20, SH110X_BLACK);
        display.setCursor(0, 20); display.println(rxText);
        display.display();
        lastRxTime = millis();
      }
    }

    if (!rxInit) {
      display.clearDisplay();
      display.setCursor(0, 0);
      display.println("I AM Rx");
      display.display();
      rxInit = true;
    }

    bool show = (millis() - lastRxTime < holdTime);
    if (show != indicatorState) {
      display.fillRect(0, 48, 128, 16, SH110X_BLACK);
      if (show) { display.setCursor(0, 48); display.println("[OTHER IS IN]"); }
      display.display();
      indicatorState = show;
    }

    if (millis() - lastRxTime > 3000) { rxText[0] = '\0'; }
  }
}